HM-ES-TX-WM/Strom-Script01: Unterschied zwischen den Versionen

!! Energy Costs Part 1                                                       
!!
!! Berechnet die verbrauchten kWh seit dem letzten Aufruf + Preis
!! sollte einmal tgl. um 0 Uhr laufen
!! 02/15                                                 
!! (c) by thkl
!!
!! Benötigte SystemVariablen:
!! Name : eCountYesterday Typ: Zahl Einheit kWh
!! Name : eCostYesterday Typ: Zahl Einheit : EUR
!! Name : eEXMemory Typ: Zeichenkette
!!
!! Verbrauchte Energie wird nach Scriptlauf in eCountYesterday in kWh gespeichert Kosten in eCostYesterday

!! serialCounter mit Seriennummer des HM Zählers füllen

var serialCounter = "XXXXX";
var dpname = "ENERGY_COUNTER";
var priceKey = "curPrice";

var eEXMemory = dom.GetObject("eEXMemory");
var svCountYesterday = dom.GetObject("eCountYesterday");
var svCostYesterday = dom.GetObject("eCostYesterday");
object devEnergyDP = dom.GetObject("BidCos-RF."#serialCounter#":1."#dpname);
string tmpSVal = eEXMemory.State();
real devcount = devEnergyDP.State();
real statelast = tmpSVal.ToFloat();
real cnyday = devcount-statelast;

string stdout;string stderr;
string cmd = "/bin/sh -c 'cat /etc/config/energyPrice|sed -r \"s/\\"//g\"'";
system.Exec(cmd, &stdout, &stderr);
string sep = "\n";
string part;
string strCur;
real price;

foreach(part,stdout.Split(sep)) {
  string key = part.StrValueByIndex(":",0);
  string val = part.StrValueByIndex(":",1);
  if (key==priceKey){
    price = val.ToFloat();
  }
  if (key=="currency") {
    strCur=val;
  }
}

eEXMemory.State(devcount.ToString());

integer kwf = 1;

if (priceKey=="curPrice") {
  kwf = 1000;
}

real costyed = price * (cnyday/kwf);
svCountYesterday.State((cnyday/kwf));
svCostYesterday.State(costyed);

!! Energy Costs Part 2                                                       
!!
!! Berechnet die verbrauchten kWh seit dem letzten Aufruf von Script 1 also im Idealfall
!! den Verbrauch seit Mitternacht
!!
!! kann beliebig oft laufen
!! funktioniert nur in Zusammenhang mit Script 1 richtig
!!
!! 02/15                                                 
!! (c) by thkl
!!
!! Benötigte SystemVariablen:
!! Name : eCountToday Typ: Zahl Einheit kWh
!! Name : eCostToday Typ: Zahl Einheit: EUR
!! Name : eEXMemory Typ: Zeichenkette
!!
!! Verbrauchte Energie wird nach Scriptlauf in eCountToday in kWh gespeichert Kosten in eCostToday

!! serialCounter mit Seriennummer des HM Zählers füllen


var serialCounter = "XXXXX";
var dpname = "ENERGY_COUNTER";
var priceKey = "curPrice";

var eEXMemory = dom.GetObject("eEXMemory");
var svCountToday = dom.GetObject("eCountToday");
var svCostToday = dom.GetObject("eCostToday");

object devEnergyDP = dom.GetObject("BidCos-RF."#serialCounter#":1."#dpname);
string tmpSVal = eEXMemory.State();
real devcount = devEnergyDP.State();
real statelast = tmpSVal.ToFloat();
real cntoday = devcount-statelast;

string stdout;string stderr;
string cmd = "/bin/sh -c 'cat /etc/config/energyPrice|sed -r \"s/\\"//g\"'";
system.Exec(cmd, &stdout, &stderr);
string sep = "\n";
string part;
string strCur;
real price;

foreach(part,stdout.Split(sep)) {
  string key = part.StrValueByIndex(":",0);
  string val = part.StrValueByIndex(":",1);
  if (key==priceKey){
    price = val.ToFloat();
  }
  if (key=="currency") {
    strCur=val;
  }
}

integer kwf = 1;

if (priceKey=="curPrice") {
  kwf = 1000;
}
real costtoday = price * (cntoday/kwf);
svCountToday.State((cntoday/kwf));
svCostToday.State(costtoday);

!! Energy Costs Part 3                                                       
!!
!! Berechnet die verbrauchten kWh/m3 seit der letzten Abrechnung des Energielieferanten
!!
!! kann beliebig oft laufen
!!
!! 02/15                                                 
!! (c) by thkl
!!
!! Benötigte SystemVariablen:
!! Name : eLastInvoice Typ:Zahl -> hier den Zählerstand der letzten Energieabrechnung in kWh oder m3 eintragen.
!! Name : eStart Typ: Zeichenkette -> hier den aktuellen Zählerstand und den Zählerstand des Energiemessgerätes in ganzen kWh eintragen und zwar wie folgt:
!! Zählerstand EZähler|Zählerstand HM Zähler (Beispiel 17456|5 ; wenn der Schwarze Kasten im E-Verteiler 17456 zeigt und gleichzeitig das HM Gerät 5) Achtung das HM Gerät zählt in WattStunden (alternativ natürlich die Gaszählerwerte)
!! also / 1000
!! Name : eUsedEnergyCost Typ: Zahl Einheit :EUR 
!! Name : eUsedEnergyCount Typ: Zahl Einheit :kWh oder m3
!! Name : eTotalEnergyCount Typ: Zahl Einheit :kWh oder m3
!! Energiekosten werden nach Scriptlauf in eUsedEnergyCost gespeichert
!! Verbrauchte KwH werden nach Scriptlauf in eUsedEnergyCount gespeichert
!! aktueller Stand des Stromzählers wird in eTotalEnergyCount gespeichert

!!

!! serialCounter = "" - Hier die Seriennummer des HM Zählregrätes eintragen

!! useAsGasCounter = 0 - E Zähler ; = 1 Gas Zähler

!! cuxddevice = Seriennummer des CuxD Exec Devices. Wenn nicht vorhanden leer lassen dann wird system.exec genommen

var serialCounter = "";

var useAsGasCounter = 0;

var cuxddevice = "";

!! ================ ab hier nichts mehr aendern

var dpname = "ENERGY_COUNTER";

if (useAsGasCounter==1) {

  dpname = "GAS_ENERGY_COUNTER";

}

var svLastInvoice = dom.GetObject("eLastInvoice");

var svMemory = dom.GetObject("eStart");

var svUsedEnergyCost = dom.GetObject("eUsedEnergyCost");

var svUsedEnergyCount = dom.GetObject("eUsedEnergyCount");

var svTotalEnergyCount = dom.GetObject("eTotalEnergyCount");

var memory = svMemory.State();

var countLastIncoice = svLastInvoice.State();

object devEnergyDP = dom.GetObject("BidCos-RF."#serialCounter#":1."#dpname);

real oec = memory.StrValueByIndex("|",0).ToFloat();

real shc = memory.StrValueByIndex("|",1).ToFloat();

real chc = devEnergyDP.State();

string stdout;string stderr;

string cmd = "/bin/sh -c 'cat /etc/config/energyPrice|sed -r \"s/\\"//g\"'";

if (cuxddevice!="") {

  dom.GetObject("CUxD."#cuxddevice#":1.CMD_SETS").State(cmd);

  dom.GetObject("CUxD."#cuxddevice#":1.CMD_QUERY_RET").State(1);

  stdout = dom.GetObject("CUxD."#cuxddevice#":1.CMD_RETS").State();

} else {

  system.Exec(cmd, &stdout, &stderr);

}

string sep = "\n";

string part;

string strCur;

real pricekwh=0;

real condvalue=0;

real heatvalue=0;

foreach(part,stdout.Split(sep)) {

  string key = part.StrValueByIndex(":",0);

  string val = part.StrValueByIndex(":",1);

  

  if (useAsGasCounter==1) {

  if (key=="gasHeatingValue"){

    heatvalue = val.ToFloat();

  }

  if (key=="gasConditionNumber"){

    condvalue = val.ToFloat();

  }

  if (key=="gasPrice"){

    pricekwh = val.ToFloat();

  }

  } else {

    if (key=="curPrice"){

    pricekwh = val.ToFloat();

  }

  }

  if (key=="currency") {

    strCur=val;

  }

}

if (useAsGasCounter==1) {

       real cec = (chc - shc)+oec;

       real uec = cec-countLastIncoice;

       real consumtion = heatvalue * condvalue * uec;

       real costyear = pricekwh * consumtion;

       svUsedEnergyCost.State(costyear);

       svUsedEnergyCount.State(uec);

       svTotalEnergyCount.State(cec);

} else {

       real cec = ((chc/1000) - shc)+oec;

       real uec = cec-countLastIncoice;

       real costyear = pricekwh * (uec);

       svUsedEnergyCost.State(costyear);

       svUsedEnergyCount.State(uec);

       svTotalEnergyCount.State(cec);

}

dom.GetObject("svEnergyCounter_XXXXX_XXXXXXXXXX:1").State(dom.GetObject("BidCos-RF.SERIENNUMMER:1.ENERGY_COUNTER").State()+12345);